Introduces an extension for ERC-721 Non-Fungible Tokens (NFTs) and Soulbound Tokens (SBTs) that adds an expiration mechanism, allowing tokens to become invalid after a predefined period. This additional layer of functionality ensures that the expiration mechanism does not interfere with existing NFTs or SBTs, preserving transferability for NFTs and compatibility with current DApps such as NFT Marketplace. Expiration can be defined using either block height or timestamp, offering flexibility for various use cases.
Introduces an extension for ERC-721 Non-Fungible Tokens (NFTs) and Soulbound Tokens (SBTs), which facilitates the implementation of an expiration mechanism.
Use cases include:
The keywords “MUST”, “MUST NOT”, “REQUIRED”, “SHALL”, “SHALL NOT”, “SHOULD”, “SHOULD NOT”, “RECOMMENDED”, “NOT RECOMMENDED”, “MAY”, and “OPTIONAL” in this document are to be interpreted as described in RFC 2119 and RFC 8174.
// SPDX-License-Identifier: CC0-1.0
pragma solidity >=0.8.0 <0.9.0;
/**
* @title ERC-7858: Expirable NFTs and SBTs
* @notice unique/granular expiry
*/
// import "./IERC721.sol";
// The EIP-165 identifier of this interface is `0x3ebdfa31`.
interface IERC7858 /**is IERC721 */ {
enum EXPIRY_TYPE {
BLOCKS_BASED, // block.number
TIME_BASED // block.timestamp
}
/**
* @dev Emitted when the expiration date of a token is set or updated.
* @param tokenId The identifier of the token ERC721 `tokenId`.
* @param startTime The start time of the token (block number or timestamp based on `expiryType`).
* @param endTime The end time of the token (block number or timestamp based on `expiryType`).
*/
event TokenExpiryUpdated(
uint256 indexed tokenId,
uint256 indexed startTime,
uint256 indexed endTime
);
/**
* @dev Returns the type of the expiry.
* @return EXPIRY_TYPE Enum value indicating the unit of an expiry.
*/
function expiryType() external view returns (EXPIRY_TYPE);
/**
* @dev Checks whether a specific token is expired.
* @param tokenId The identifier representing the `tokenId` (ERC721).
* @return bool True if the token is expired, false otherwise.
*/
function isTokenExpired(uint256 tokenId) external view returns (bool);
// return depends on the type `block.timestamp` or `block.number`
// {ERC-5007} return in uint64 MAY not suitable for `block.number` based.
function startTime(uint256 tokenId) external view returns (uint256);
function endTime(uint256 tokenId) external view returns (uint256);
}
balanceOf that inherited from ERC-721 MUST return all tokens even if expired; they still exist but are unusable due to the limitation of tracking expired token on-chain.transferFrom, and safeTransferFrom MUST allow transferring tokens even if they expired. This ensures that expired tokens remain transferable and tradable, preserving compatibility with existing applications already deployed. However, expired tokens MUST be considered invalid and unusable in contracts that check for token validity.expiryType MUST return the type of expiry used by the contract, which can be either BLOCK or TIME.isTokenExpired is used for retrieving the status of the given tokenId the function MUST return true if the token is expired and MUST revert if the tokenId does not exist for implementation that use custom error SHOULD revert with ERC721NonexistentToken following the relevant ERC-6093 and for implementation that using Solidity version below v0.8.4 or those preferring to use revert with string error SHOULD revert with NonexistToken, If the tokenId exists and is not expired, the function MUST return false.startTime and endTime of tokenId, can be block.number or block.timestamp depending on expiryType. The startTime MUST less than endTime and SHOULD except when both are set to 0. A startTime and endTime of 0 indicates that the tokenId has no time-limited. If the tokenId does not exist MUST revert same as in function isTokenExpired.supportInterface for IERC7858 is 0x3ebdfa31 for IERC7858Epoch is 0x8f55b98aTokenExpiryUpdated MUST be emitted when the token is minted or when its expiration details (startTime or endTime) are updated.Epochs represent a specific period or block range during which certain tokens are valid borrowing concepts from ERC-7818, tokens are grouped under an epoch and share the same validityDuration.
// SPDX-License-Identifier: CC0-1.0
pragma solidity >=0.8.0 <0.9.0;
/**
* @title ERC-7858: Expirable NFTs and SBTs
* @notice epoch expiry extension
*/
// import "./IERC7858.sol";
// The EIP-165 identifier of this interface is `0x8f55b98a`.
interface IERC7858Epoch /** is IERC7858 */ {
/**
* @dev Retrieves the current epoch of the contract.
* @return uint256 The current epoch of the token contract,
* often used for determining active/expired states.
*/
function currentEpoch() external view returns (uint256);
/**
* @dev Retrieves the duration of a single epoch.
* @return uint256 The duration of a single epoch.
* @notice The unit of the epoch length is determined by the `validityPeriodType` function.
*/
function epochLength() external view returns (uint256);
/**
* @dev Returns the type of the epoch.
* @return EXPIRY_TYPE Enum value indicating the unit of an epoch.
*/
function epochType() external view returns (EXPIRY_TYPE);
/**
* @dev Checks whether a specific `epoch` is expired.
* @param epoch The `epoch` to check.
* @return bool True if the token is expired, false otherwise.
* @notice Implementing contracts "MUST" define and document the logic for determining expiration,
* typically by comparing the latest epoch with the given `epoch` value,
* based on the `EXPIRY_TYPE` measurement (e.g., block count or time duration).
*/
function isEpochExpired(uint256 epoch) external view returns (bool);
/**
* @dev Retrieves the balance of unexpired tokens owned by an account.
* @param account The address of the account.
* @return uint256 The amount of unexpired tokens owned by an account.
*/
function unexpiredBalanceOf(address account) external view returns (uint256);
/**
* @dev Retrieves the balance of a specific `epoch` owned by an account.
* @param epoch The `epoch for which the balance is checked.
* @param account The address of the account.
* @return uint256 The balance of the specified `epoch`.
* @notice "MUST" return 0 if the specified `epoch` is expired.
*/
function unexpiredBalanceOfAtEpoch(uint256 epoch, address account) external view returns (uint256);
/**
* @dev Retrieves the validity duration of each token.
* @return uint256 The validity duration of each token in `epoch` unit.
*/
function validityDuration() external view returns (uint256);
}
unexpiredBalanceOfAtEpoch MUST return unexpired or usable balance of tokens held by an account at the specified epoch,If the specified epoch is expired, this function MUST return 0. For example, if epoch 5 has expired, calling unexpiredBalanceOfAtEpoch(5, address) returns 0 even if there were tokens previously held in that epoch.unexpiredBalanceOf MUST return only unexpired or usable tokens.currentEpoch MUST return the current epoch of the contract.epochLength MUST return duration between epoch in blocks or time in seconds.epochType MUST return the type of epoch used by the contract, which can be either BLOCKS_BASED or TIME_BASED.validityDuration MUST return the validity duration of tokens in terms of epoch counts.isEpochExpired MUST return true if the given epoch is expired, otherwise false.These OPTIONAL functions provide additional functionality that might be useful depending on the specific use case.
getRemainingDurationBeforeTokenExpired returns the remaining time or blocks before the given tokenId is expired.getEpochBalance returns the amount of tokens stored in a given epoch, even if the epoch has expired.getEpochInfo returns both the start and end of the specified epoch.getNearestExpiryOf returns the list of tokenId closest to expiration, along with an estimated expiration block number or timestamp based on epochType.getRemainingDurationBeforeEpochChange returns the remaining time or blocks before the epoch change happens, based on the epochType.Introducing expirability as an additional layer of functionality ensures it doesn’t interfere with existing use cases or applications. For non-SBT tokens, transferability remains intact, maintaining compatibility with current systems. Expired tokens are simply flagged as unusable during validity checks, treating expiration as an enhancement rather than a fundamental change.
Defining expiration by either block height (block.number) or block timestamp (block.timestamp) offers flexibility for various use cases. Block-based expiration suits applications that rely on network activity and require precise consistency, while time-based expiration is ideal for networks with variable block intervals.
This standard is fully compatible with ERC-721, ERC-5484 and other SBTs.
You can find our reference implementation here.
Implementation should ensure that burning token and re-minting it with the same tokenId will not introduce an unauthorized renewal.
Copyright and related rights waived via CC0.